Useful macros for priests

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

3.1 Discipline Macros

Disc Priest Main Heal (Mouse Up)

#showtooltip Penance
/stopmacro [channeling]
/console Sound_EnableSFX 0
/use 13
/use 14
/castsequence [harm] , Smite; , Flash Heal
/cast Penance
/console Sound_EnableSFX 1
/script UIErrorsFrame:Clear()

• Use: This casts Penance, or Flash Heal or Smite based on what is available and what you are targeting.
• Focus: Universal
• Validated: 3.1

Disc Priest Main Prevention (Mouse Down)

#showtooltip
/dismount [mounted]
/castsequence [group, harm] !Shoot; [harm] reset=5/target Shadow Word: Pain, Devouring Plague, Power Word: Shield; reset=target/2 Power Word: Shield, Renew

• Use: This puts a Shield on Friendly targets, DOTs on enemies to lead off combat. When you are in a group it wands.
• Focus: Universal
• Validated: 3.1

3.1 Shadow Macros

Shadow Priest All In One (Mouse Up)

#showtooltip Mind Blast
/stopmacro [channeling]
/use 13
/use 14
/castsequence reset=11 , Mind Blast, Shadow Word: Death, Mind Flay, Mind Blast, Mind Flay, Mind Flay
/cast Devouring Plague
/script UIErrorsFrame:Clear()

• Use: Casts Mind Blast, SWD, Mind Flay or Devouring Plague
• Focus: PVE
• Validated: 3.1

3.1 All Priest Macros

Spamable Mind Sear

#showtooltip Mind Sear
/stopmacro [channeling]
/cast Mind Sear

• Use: Spamable Mind Sear, won't interrupt or clip your channel by pressing the button by repeatedly pressing the button.
• Focus: PVE
• Validated: 3.1

Harm vs. Help Space Saving Macros

#showtooltip
/cast [harm] Smite; Flash Heal

• Use: Saves space by having the same button cast Smite on bad guys, and Flash Heal on good guys. Mix and match heal/harm spells based on what your key binding preferences.
• Focus: Universal
• Validated: 3.1

#showtooltip
/castsequence [harm] reset=6 Holy Fire, Smite, Smite, Smite; Flash Heal
/use 13
/use 14

• Use: This is a more complicated example of a Harm vs. Help macros.
• Focus: Universal
• Validated: 3.1

OLD MACROS BELOW

The macros below this line have not been validated to work in 3.1. Use at your own risk.

Guardian Spirit on focus

This macro casts Guardian Spirit on your focus. I always set the tank to be the focus during heroics so that I can get a good view of his buffs, debuffs, and watch his target (out of interest) without having to mess about on screen while I should be healing.

The final line is entirely optional. It's designed to put a shield on a target that you may have been halfway through a Greater Heal on before casting Guardian Spirit on the focus. This buys your previous target a little more time while you recast the heal.

1. show Guardian Spirit

/stopcasting /cast [target=focus] Guardian Spirit /cast Power Word: Shield

Damage dealing macro for low levels

This macro unifies spells for doing damage:

#showtooltip
/cast [mod:alt, target=player] Power Word: Shield
/cast [nomod:alt, nocombat] Smite
/castsequence [nomod:alt, combat] reset=combat/target Shadow Word: Pain, Mind Blast, Smite, Smite

What the macro does:

1. The first line allows you cast [Power Word: Shield] whenever the alt key is pressed (at any time)
2. The second line is for starting an attack. Target some enemy, then press the button and it will cast [Smite]
3. The third line is the sequence that will be cast while you're in combat (for levels below 10, remember to remove [Mind Blast] from the macro).

Assign this macro to some key, then assign another key for [Lesser Heal] (or [Renew]) and another for Shoot (or Attack, if you don't have a wand) so that you only need 3 command keys.

I use this macro in the following way:

• I can cast Power Word: Shield either before the attack, in the middle or I don't cast it at all.
• The second line only works if I'm attacking the target first. In that case I have time to spend casting Smite. If the enemy attacks me first, then the third line enters into action, avoiding the slow Smite cast.
• After the sequence casts Mind Blast, I choose between using zero, one or two Smites before switching to melee attack. Then I can either finish the cycle and repeat or kill the enemy with a final Smite.

An interesting hint in line two is that if you're fast enough you can cast two Smites before you actually enter combat. I usually cast two non-combat Smites if I'm very far from the enemy.

This macro is good for playing with levels below 20.

Telling res

This macro will send a tell to the player you have your mouse over, this is great for seeing if the ressie is online, you will still need to click the ressie to give them the res :)

#showtooltip
/script SendChatMessage("WTS out of combat res, only 100G !!!", "WHISPER", nil, UnitName("mouseover"));
/cast Resurrection

you free to change the message send by editing "WTS out of combat res, only 100G !!!" just leave the "" in the macro :) You can also add in

/say I am resurrecting %t

at the end if you wish :)

Stopcasting, the Raid Healers' Friend

This one command is a requirement in all [Greater Heal] usage for Raid healers. It is not proper to jump or move to interrupt casting (this can mean wipes on certain fights). The Priest should always have a heal casting and cancel it by using a heal with the /stopcasting command. Since downranking is no longer supported, Consider having macros made for Greater Heal and Renew. You may also want to try Power Word: Shield and Dispel Magic for emergencies, but these are instant casts, one with cooldown one with dual functionality, so use caution before heading out to a raid or PVP battle with them.

/stopcasting
/cast [target=mouseover,exists] Greater Heal

/stopcasting
/cast [target=mouseover,exists] Renew

Or one that casts Greater Heal on your target if it is friendly and on your mouseover if not

/stopcasting
/cast [help] Greater Heal; /cast [harm] [target=mouseover,exists] Greater Heal

Greater Heal mob's target or friendly target

This macro will cast Greater Heal on your target if your target is friendly; if your target is an enemy, it will cast Greater Heal on your target's target.

/cast [help][target=targettarget][] Greater Heal

Use this macro to heal yourself when holding down alt. These also work with any other heal.

#showtooltip Greater Heal
/cast [help, nomodifier:alt][nomodifier:alt, target=targettarget][modifier:alt, target=player][] Greater Heal

Left click PW:F, Right Click PoF

Left click casts single target [Power Word: Fortitude], right click casts group-wide [Prayer of Fortitude]. Works with other comparable spells as well, such as Divine Spirit, Shadow Protection, Mark of the Wild, Arcane Intellect, or any of the paladin blessings.

/cast [button:2] Prayer of Fortitude; Power Word: Fortitude

Resurrection if able — announce to raid if it works on target

Does not execute if you're in combat or in Shadowform. Selects resurrection for casting on next click if your target is not friendly or not dead.

/stopmacro [stance:1][combat]
/cast Resurrection
/stopmacro [nohelp][nodead]
/ra Resurrecting %t.

Shield Self without losing healing target

On one button press you can use Power Word: Shield on yourself without losing your current healing target.

/cast [target=player]Power Word: Shield

Mouse Over Heal

This macro will allow you to mouseover a party member and heal them. Also works nicely for Power Word: Fortitude.

/cast [target=mouseover,exists][] Flash Heal

This macro will cast renew or heal on a single target, in the following order:

If target is friendly

If the mouse is over a friendly target

If the target is hostile, then on the target's target

If no target, then player

/castsequence [help] [target=mouseover,help,exists] [target=targettarget, help, exists] [target=player] reset=target/5 Renew, Heal

The following will also self cast if the player holds alt, no matter what is moused over or targeted:

/stopcasting
/cast [nomodifier:alt,target=mouseover,nodead,help][nomodifier:alt,help,nodead][nomodifier:alt,target=targettarget,nodead,help][nomodifier:alt,target=player][modifier:alt,target=player]Greater Heal

Its order is Mouseover -> target -> target's target -> self, holding down alt will skip to self.

One Button Renew or SW:Pain

This macro casts either Renew (friendly) or Shadow Word: Pain (hostile) on whoever is hovering under your mouse that exists and is not dead. If you're not hovering, it does either Renew (friendly) or Shadow Word: Pain (hostile) on your selected target that is not dead. If all of the above are false, you will Renew yourself.

/cast [target=mouseover,exists,help,nodead] Renew; [target=mouseover,exists,harm,nodead] Shadow Word: Pain; [help,nodead] Renew; 
[harm,nodead] Shadow Word: Pain; [target=player] Renew

A different version of the above macro (make self-cast available with alt, removes some redundancies):

/cast [target=player,modifier:alt] [target=mouseover,help,nodead] Renew; [target=mouseover,harm,nodead] Shadow Word: Pain;
[help,nodead] Renew; [harm,nodead] Shadow Word: Pain; [target=focus,exists] [target=player] Renew

What it does (if condition isn't met, move on to the next):

If holding ALT, cast Renew on yourself.

If mousing over an ally, cast Renew on them.

If mousing over an enemy, cast Shadow Word Pain on them.

If targeting an ally, cast Renew on them.

If targeting an enemy, cast Shadow Word Pain on them.

If you have a focus, cast Renew on them.

If all else fails, cast Renew on yourself.

This could also be easily applied to any other spell combination (Holy Fire/Heal, Smite/Flash Heal, for example).

Rebuff yourself

This macro rebuffs the player. Multiple clicks are required.

 /cast [nostance] Shadowform
 /castsequence [target=player,stance:1] Inner Fire, Power Word: Fortitude, Shadow Protection, (Racial Priest Spell)

This macro will do the following:

If target is hostile

cast a spell then start using your wand (requires two keypresses)

If target is friendly

cast buff

if no target

cast buffs on player (requires key press for each buff)

/castsequence [harm]  reset=target/18 Shadow Word: Pain, Shoot
/stopmacro [harm]
/cast [help] [target=targettarget, help, exists] Power Word: Fortitude
/castsequence [target=player] reset=5 Inner Fire, Power Word: Fortitude

This macro is a bit more precise than the above one and allows for castsequence to friendly targets.

If the target is friendly

then buff target

If the target is hostile

Then damage

If no target

Then buff self

/castsequence [help] reset=target/5 Power Word: Fortitude, Shadow Protection
/castsequence [harm] reset=target/18 Shadow Word: Pain, Shoot
/castsequence [target=player] reset=15 Inner Fire, Shadow Protection, Power Word: Fortitude

Just an easy selfbuff if you feel you would like to have it in another order, just change the spell's position.

/castsequence [target=player]  reset=20/ Inner Fire, Power Word: Fortitude, Shadow Protection

Shackle Undead and focus on target

This macro will first shackle your current target and set that target to be your focus target. This will allow you to reshackle a mob without having to retarget it.

#showtooltip Shackle Undead
/clearfocus [modifier:alt][target=focus,dead][target=focus,help][target=focus,noexists]
/focus [target=focus,noexists]
/cast [target=focus]Shackle Undead

If you want to announce your shackle add a line like this to the end of the macro

/raid Shackling %f

Ultimate Mind Control Macro

This macro will first Mind Control your current target and set that target to be your focus target. This will allow you to Mind Control again with another click without having to change targets. When you are ready to release, right click will release your Mind Control, cast Fade, re-target the Mind Controlled enemy, clear focus, and announce that you have released your mind control.

#showtooltip Mind Control
/focus [target=focus,noexists]
/cast [nobtn:2,target=focus]Mind Control
/stopmacro [nobtn:2]
/script PetDismiss()
/cast Fade
/target focus
/clearfocus
/stopmacro [nogroup]
/s Mind Control Released!

Instructor Razuvious Mind Control

This macro will help you on the Naxxramas 25 fight versus Instructor Razuvious. It allows you to Mind Control your designated Understudy (focus target) and target the Instructor right after, so you can use taunt right away if necessary. If you set up a focus macro as well, you can switch to another Understudy quickly if yours dies.

#showtooltip
/cast [target=focus] Mind Control
/tar Instructor

#showtooltip
/focus

Use trinket, cast Inner Focus, and cast Devouring Plague

Obviously useful only for priests with Inner Focus talent. You have to change trinket's name to the one you own and want to use (trinket has to be equipped). This macro will also prevent wasting trinket's and Inner Focus's cooldowns if your target is accidentally friendly or simply cannot be attacked.

 #showtooltip Devouring Plague
 /use [harm] Xi'ri's Gift
 /cast [harm] Inner Focus
 /stopcasting
 /cast Devouring Plague

For Healing with Trinket

 #showtooltip Heal trinket
 /use 13
 /use 14
 /cast Inner Focus
 /cast Greater Heal

Cast Silence if available, otherwise cast Arcane Torrent

This macro will cast the Silence spell. If Silence is on cooldown, it will cast Arcane Torrent. Obviously, this macro is only of use to Blood Elves.

 /castsequence reset=45 Silence, Arcane Torrent

Spammable Mind Flay

This macro will allow you to spam Mind Flay without interrupting the one already channeling.

#showtooltip Mind Flay
/cast [nochanneling:Mind Flay] Mind Flay

Change stance and cast depending on target reaction

This macro will look at your stance and your current target. If the target is hostile and you are in Shadowform Mind Blast will be cast, if you are not in Shadowform it will put you into it. Will do the same for Flash Heal if the target is friendly and change your stance accordingly.

 /cast [stance:1,harm] Mind Blast; [stance:1,help] Shadowform; [nostance,help] Flash Heal; [nostance,harm] Shadowform

This macro is the same as above but will start a grind sequence to kill the mobs with nice mana efficiency. The targeting of a friendly target will cast Flash Heal then Renew.

 /use 14
 /use 13
 /castsequence [stance:1,harm] reset=target/combat Vampiric Touch, Shadow Word: Pain, Vampiric Embrace, Mind Flay, Mind Blast, Shoot; [stance:1,help] Shadowform; [nostance,help] Flash Heal, Renew; [nostance,harm] Shadowform

The Polite Reply

Make those whispers less hassle with a polite reply when needed.

/r I'm not a healbot. Good luck!

Mouseover Flash Heal on friendly, Mind Blast on enemy

Cast Flash Heal if mouseover a friendly target, Mind Blast if over an enemy. If mouse is over nothing, it will cast on the current target. The only drawback is you will need to have a set of self cast macros.

#showtooltip
/cast [target=mouseover,noharm,exists] Flash Heal;[target=mouseover,harm,exists] Mind Blast;[noharm]Flash Heal;[harm]Mind Blast

Will of the Forsaken and Fear Ward

This will cast Will of the Forsaken and then Fear Ward without losing your target. Mostly a PvP macro. It requires 2 button presses.

#showtooltip Will of the Forsaken
/castsequence reset=5 [target=player]Will of the Forsaken,Fear Ward

Dispel Magic

This will dispel magic on your target, should one exist. If not, then it will work like a normal Dispel Magic. Right-Clicking will cast it on you.

#showtooltip
/cast [btn:1,exists,nodead][btn:1][btn:2,target=player] Dispel Magic

Stingy Raid Priest

Alt-clicking this will toggle to the next nearby friendly player. Then each click will cast a separate buff. This is particularly useful in battlegrounds.

#showtooltip 
/targetfriend [modifier:alt]
/castsequence [nomodifier] reset=target/5 Power Word: Fortitude, Divine Spirit, Shadow Protection

Shield target or self

Shields target if it is in your party/raid, otherwise shields you.

#showtooltip
/cast [group,help][target=player] Power Word: Shield

Wand On

This is a wand macro that helps prevent you from accidentally switching off your wand's shoot.

#shoot
/cast !shoot

Normally using your wand toggles 'shoot' on and off. This macro keeps it switched on. So if you accidentally press it twice, it'll still keep shooting. It works most of the time (unless you really mash the key).

The ! exclamation is the key to this. It stops the toggle. If you want to stop shooting, jump, move, re-target or kill the mob.

Starshards and SW:Pain (Now Defunct)

Two presses the first does SW:Pain the second does Starshards (which has a 30 sec cooldown). To reset, click another mob, click away, or ctrl click. Resets when you leave combat too.

 /startattack 
 /castsequence reset=30/target/combat/ctrl Shadow Word: Pain, Starshards

Super PoM

This macro starts by attempting to PoM the target of whatever enemy you have selected. It's perfect in PvP for helping out the target of the enemy player you select, and it's perfect in PvE for getting an instant heal in on someone who may have accidentally pulled aggro. If you have no target selected, it attempts to PoM your Focus if you have one set up. If neither of those happen, you will PoM yourself.

 /cast [help][target=targettarget,help][target=focus,help][target=player] Prayer of Mending

Self-Cast when solo/standard casting when in party/raid

This macro will work for any beneficial spell — buffs and heals. When solo, whatever spell you have it set up for will be cast on self. When in a party or raid, it will either cast the spell on your current target or give you the standard click-on-target-to-cast - the same as if you were using no macro for the spell at all.

#showtooltip
/cast [nogroup,target=player] [group,help] [group,target=none] <Spellname>

Replace spellname with the spell you would like to use it for. The one drawback of this macro is that when you are solo, you cannot cast buffs on random people you pass without going to your spellbook.

Easy Shadowfiend

This macro will summon your Shadowfiend on your current target if it is hostile, or your target's target if your current target is friendly.

#showtooltip Shadowfiend
/cast [harm,nodead][target=targettarget,harm,nodead]Shadowfiend

Shield Shadowfiend

This macro will force the pet to auto attack either your target or the target of whoever you are healing. Also by clicking the macro a second time it will shield your Shadowfiend (thus reducing the chance your pet will die). Overall you will recover more mana.

#showtooltip Shadowfiend
/castsequence [target=pet,exists,nodead] Power Word: Shield; [harm,nodead][target=targettarget,harm,nodead]Shadowfiend

Kevin Bacon Shadowfiend

Not really. Just goes five levels deep instead of six. This macro will cast Shadowfiend on the first hostile target of target of ... target. Two levels isn't quite enough for raids. Think raid healer targeting tank healer targeting tank targeting boss. And if you have to go three levels deep, you might as well go five.

#showtooltip Shadowfiend
/cast [harm,nodead][target=targettarget,harm,nodead][target=targettargettarget,harm,nodead][target=targettargettargettarget,harm,nodead][target=targettargettargettargettarget,harm,nodead]Shadowfiend

I'm under attack!

This is possibly the most important macro a party/raid healer can have. Put it in an easily accessible action bar slot, or bind it to something convenient.

/rw The healer is under attack!
/helpme

Particularly useful while pugging. Gets a near instantaneous response out of most tanks (and the beefier DPS will typically run to your aid, too). Without it, party members will often simply not notice that you've drawn aggro until you have died. Variants include using /p or /y instead of the raid warning. However, I have found that in the kind of sticky situations where you NEED the macro, party members are far too distracted to notice party chat or a yell; the raid warning never fails.