Useful macros for warlocks

Macros
General guides
Macros Beginners Guide Making a macro Macro conditionals Macro commands Category:Macros
Useful macros by class

OLD MACROS BELOW

The macros below this line have not been validated to work in 3.1. Use at your own risk.

General Macros

The conditional for Metamorphosis is [form:2].

Always Use Metamorphosis, Demonic Empowerment and Trinkets

When activated, this will use any available trinket, cast Metamorphosis, cast [Demonic Empowerment] when an Imp or Felguard is summoned, and cast your regular spell. Change all occurrences of Curse of Agony to the spell of your choice.

#showtooltip Curse of Agony
/use 13
/use 14
/cast Metamorphosis
/cast [pet:Felguard] [pet:imp] Demonic Empowerment
/script UIErrorsFrame:Clear()
/cast Curse of Agony

This version allows for focus casting when the ALT key is held.

#showtooltip Curse of Agony
/use 13
/use 14
/cast Metamorphosis
/cast [pet:Felguard] [pet:imp] Demonic Empowerment
/script UIErrorsFrame:Clear()
/cast [modifier:alt,target=focus] Curse of Agony
/cast [nomodifier,target=target] Curse of Agony

Both versions will stop error messages from appearing on your screen but audible messages will still occur so you may wish to turn off Error Speech in the sound options.

---

This version will turn the error speech off during the casting and back on once it is done. It will NOT remove the visual error messages.

#showtooltip shadow bolt
/console Sound_EnableSFX 0
/use 13
/use 14
/cast Metamorphosis
/cast Demonic Empowerment
/cast shadow bolt
/script UIErrorsFrame:Clear()
/console Sound_EnableSFX 1

Life Tap at Maximum and Minimum Level

When activated without a modifier, this macro will cast the highest level of Life Tap available to your character. When ALT is held, it will cast the lowest.

#showtooltip Life Tap
/cast [modifier:alt] Life Tap(Rank 1)
/cast [nomodifier] Life Tap

Always Use Trinkets

When you have one or two trinkets that have a use effect that increases spell damage or some other kind of effect that you always want in use during combat you normally have use them manually or at best, click a button for it in the hot bar.

This macro will allow you to use whichever trinket is not on cooldown and cast one of the spells that it helps without causing an error message to appear due to either one or both of the trinkets being on cooldown.

#showtooltip Shadow Bolt
/use 13
/use 14
/script UIErrorsFrame:Clear()
/cast Shadow Bolt 

This version allows you to press the ALT key to cast the spell on your [focus] instead of your target. Works best with the [FocusFrame] add-on.

#showtooltip Shadow Bolt
/use 13
/use 14
/script UIErrorsFrame:Clear()
/cast [modifier:alt,target=focus] Shadow Bolt
/cast [nomodifier,target=target] Shadow Bolt
/clearfocus [target=focus, dead] 

Fire or Shadow casting

Sometimes you'll want to ONLY cast fire or shadow spells at a target, most notably fire elementals who are immune to fire. Here's a couple of macros to do so. To start out, hold down alt while clicking the button to cast the appropriate curse on the target (or cast a different curse, such as CoA beforehand). After that, click away till dead. The fire macro seems to work better for Demonology specced locks. Feel free to substitute your own talent spells or rearrange the order.

#showtooltip
/castsequence [mod:alt] Curse of the Elements; reset=10/target/combat Immolate, Incinerate, Searing Pain, Incinerate

#showtooltip
/castsequence [mod:alt] Curse the Elements; [mod:ctrl] Shadow Bolt; reset=10/target/combat Corruption, Shadow Bolt, Shadowburn, Shadow Bolt, Seed of Corruption, Shoot (if your wand is shadow damage)

Affliction DoT castsequence

When used, this macro will first cast Immolate, Curse of Agony, Corruption and finally Siphon Life on your target. If the button is left unpressed for 10 seconds or you change your target it will reset the sequence and the next spell that will be cast will be Immolate.

#Showtooltip
/castsequence reset=10 Immolate, Curse of Agony, Corruption, Siphon Life

This macro will utilize and maximize your DPS(Damage Per Second) and wont conflict with the DoTs(Damage Over Time) duration on your situated target.

---

A slightly diffrent cast sequence putting Siphon Life first and Corruption second to make sure it is almost complete when you follow this sequence with Haunt (Will reset Corruption), and including Life Tap at the end.

#Showtooltip
/castsequence reset=10 Siphon Life, Corruption, Curse of Agony, Life Tap

These are all instant cast and can be done very quickly. If you are low on health, just don't click 4 times and you avoid the Life tap.

Immolate & Incinerate in one button

On regular click this will cast Immolate, hold down alt to cast Incinerate.

#showtooltip
/cast [modifier:alt] Incinerate; Immolate

Make sure that you select the "question mark" for the icon for the button so the proper icon will show up (Immolate as it's default). When you hit "Alt" the button will change to show the Incinerate icon.

PvP Prep

Buff Party - Invisibility

#showtooltip
/targetfriend
/cast Detect Invisibility

Buff Self - Armor/Pats

PvP with Pet This one buffs you with Fel Armor, Soul Link, Detect Invisibility, and Unending Breath. The reason you have the last two buffs is that it makes it harder for hunter, priests, etc. to dispel your Fel Armor.

#showtooltip
/castsequence [target=player] Fel Armor, Soul Link, Detect Invisibility, Unending Breath

This macro will summon your Voidwalker if he's not already out. Feel free to substitute different pets/armors if your situation differs!

/cast [nopet] Fel Domination
/castsequence [nopet] Summon Voidwalker(Summon);[pet] Demonic Sacrifice
/cast [pet] Demon Armor

And another one, especially useful after a pet has been killed, sacrificed, or dismissed. Summons your steed after your buffs, so you can get back to the action.

#showtooltip
/castsequence [nopet,mod:alt] Summon Voidwalker; [nopet,mod:ctrl] Summon Felhunter; [nopet] Summon Felguard; [pet] reset=4 Soul Link, Demon Armor, Summon Dreadsteed

Grind Macro

This is intended for grinding. The assumption is that you have the following spells: Curse of Agony, Corruption, Drain Life, Health Funnel and Drain Soul. You should have some level of these spells by level 12. After that point, the macro will just use the most advanced version of each spell (except Drain Soul). The Voidwalker or Felguard are good pets when using this macro.

To use, simply press the button when each spell is finished. To drain the soul (and create a soul shard)hold down the <Alt> key while pressing the button.

/petattack
/cast [mod:alt] Drain Soul
/cast [nocombat] Curse of Agony
/castsequence reset=target/combat Corruption,Life Tap,Drain Life,Health Funnel,Shoot

Here is the same macro with Amplify Curse (in case you have it)

/petattack
/cast [mod:alt] Drain Soul
/cast [nocombat] Amplify Curse
/cast [nocombat] Curse of Agony
/castsequence reset=target/combat Corruption,Life Tap,Drain Life,Health Funnel,Shoot

And another one (without pet attack):

#showtooltip
/castsequence [mod:ctrl] Searing Pain; [mod:alt] Incinerate; reset=10/combat/target Immolate, Corruption, Incinerate, Life Tap, Drain Life, Searing Pain

And another one (with pet attack):

/petattack
/castsequence [mod:ctrl] Searing Pain; [mod:alt] Incinerate; reset=10/combat/target Immolate, Corruption, Incinerate, Life Tap, Drain Life, Searing Pain

Grind, amplified, no error noise or message

/petattack [nocombat]
/console Sound_EnableSFX 0
/use item:31615
/console Sound_EnableSFX 1
/script UIErrorsFrame:Clear();
/castsequence reset=5/target Unstable Affliction,Immolate,Curse of Agony,Corruption,Siphon Life

The above macro sends your pet against the target, then turns off the error sound and uses the Ancient Arcane Draenei Relic to get plus spell power (but uses its item number to stay under the 255 character limit). Then it clears the red error message and turns the error sound back on (so if a spell gets blocked you hear it and see the message) and starts the grind cast sequence Unstable Affliction, Immolate, Curse of Agony, Corruption, and Siphon Life. The sequence resets if you get a new target or if 5 seconds pass. Note that Drain Life and Drain Soul are not included. I find that I prefer having them on a separate keys since I often use them out of sequence.

Trinkets + Curse of Doom

This macro will use your available Trinket, cast Amplify Curse, and Curse of Doom all in one button.

#showtooltip Curse of Doom
#show Curse of Doom
/use 13
/stopcasting
/use 14
/stopcasting
/cast Curse of Doom

Be wary this will still cast Curse of Doom regardless if you have a trinket or Amplify Curse available.

Note: As of 2.3 this macro may require a second click to cast Curse of Doom. Note: As of 3.0.2 Amplify Curse is a passive ability, decreasing Curse GCD by .5 seconds.

Multidrain

All three drains on a single button (via ctrl and alt).

 /stopmacro [noharm]
 /cast [nomodifier,nochanneling:Drain Soul(Rank 1)] Drain Soul(Rank 1)
 /cast [modifier:ctrl,nochanneling:Drain Mana] Drain Mana
 /cast [modifier:alt,nochanneling:Drain Life] Drain Life

Same macro, more space efficient.

#showtooltip
/cast [mod:ctrl] Drain Mana; [mod:alt] Drain Life; Drain Soul

If you do NOT want to be able to start your drain over before it is completely channeled, use this instead:

#showtooltip
/cast [mod:ctrl,nochanneling:Drain Mana] Drain Mana; [mod:alt,nochanneling:Drain Life] Drain Life; [nochanneling:Drain Soul] Drain Soul

Mount flying or dreadsteed

If you are in a zone where you can use your flying mount this macro will use that. If not it will summon your dreadsteed.

 /stopmacro [flying]
 /cast [outdoors,nomounted,nomodifier:ctrl,flyable] Ebon Gryphon; [outdoors,nomounted] Summon Dreadsteed(Summon)
 /dismount [mounted]

As an alternative a more advanced macro can be used. This differs from the above form in that it shows the appropriate tooltip based on what mount you are able to currently use. It also allows the use of the ALT key to summon the Dreadsteed within areas that allow flying. This macro also prevents you from accidentally dismounting while in the air. The outdoor check was omitted to save space.

#showtooltip [mod:alt] Summon Dreadsteed; [flyable] Tawny Windrider; Summon Dreadsteed
/cast [nomounted, mod:alt] Summon Dreadsteed; [nomounted,flyable] Tawny Windrider; [nomounted] Summon Dreadsteed
/dismount [mounted,noflying]

Same concept as the above macro, but will allow you to summon your Dreadsteed by pressing ctrl even in a flyable area, if you so desire. Also enables you to summon a minion of your choice (in this example a Felguard). Replace with your windrider and minion of choice.

#showtooltip
/cast [mod:ctrl] Summon Dreadsteed; [mod:alt] Summon Felguard; [flyable] Blue Windrider; Summon Dreadsteed
/dismount [noflying,mounted]

Crowd Control

Fear / Banish Focus Macro

This is a rather complex macro, utilizing focus to keep track on the target. Casting fear or banish will hit your target as well as create a focus of which all consecutive fears and banishes will target. Having a dead focus will be treated as if you had no focus.

• No modifier casts Howl of Terror
• Alt fears the target
• Ctrl banishes the target
• Ctrl+Shift banishes down-ranked
• Shift clears your focus

/cast [nomod]Howl of Terror
/stopmacro [nomod]
/focus [mod:shift,nomod:ctrl]none;[target=focus,harm,nodead]focus;[harm,nodead];none
/cast [target=focus,mod:alt]Fear;[target=focus,mod:ctrl,mod:shift]Banish(Rank 1);[target=focus,mod:ctrl]Banish

Chain-Fear Focus Macro

• If you do not have a focus it will set focus on your mouseover target.
• It will cast fear on your focus.
• If you do not have a focus, it will cast fear on your target.
• Will null your focus if you click the macro button with the control key held down, or if your target is dead.

#showtooltip
/focus [target=focus, noexists][target=focus, dead] mouseover
/cast [nomodifier, target=focus] Fear
/stopmacro [nomodifier]
/clearfocus [modifier:ctrl]

Note that if you select the macro picture the first line of the macro will make this icon the fear spell, and will allow your usual tooltip to display

Pet Macros

Pet management

Both your warlock and pet can engage the same target at the same time, given a long-casting opener and a modifier key.

/petattack [modifier]
/cast Shadow Bolt

Pet Attack Toggle

Pet attack toggle button.

/petattack [target=pettarget,noexists]
/petfollow [target=pettarget,exists]

Pet Attack => Grind

This one also makes sure your pet is attacking the target; useful to take some of the finger-work out of grinding. You'll want to fine-tune the sequence depending on your level, spec, and the mobs you're fighting.

/petattack
/castsequence reset=combat/target Corruption, Curse of Agony, Life Tap, Drain Life, Shoot

This one has two behaviors depending on whether you are in combat or not.

• Not in combat, it will send the pet and start a Shadow Bolt of your highest rank. If you hold ctrl down out of combat, it will instead start with a Curse of Recklessness WITHOUT sending the pet. This is a typical "pull to me" use where it is assumed your pet can/will taunt the mob off you asap. Usually, your pet will engage the mob before your Shadow Bolt actually strikes the mob. Wait carefully before proceeding to the in combat chain (below).
• In combat, it will start casting with Curse of Agony WITHOUT changing the pet's current target. This is useful in cases where you have already caught aggro as well as cases where you change your target to another mob (e.g., you got an "add.") NB: If you pulled with Recklessness (or any other curse), it will change to Agony.

The castsequence you can view below; you may wish to change the spells used or add/insert spells into the chain. As is typical with macros like this, you press it once to begin the actions, then wait for appropriate cooldowns before pressing it again. Recommended: The ? icon for this macro.

/cast [nomodifier:ctrl,nocombat] Shadow Bolt; [nocombat]Curse of Recklessness
/petattack [nomodifier:ctrl,nocombat]
/castsequence [combat] reset=target Curse of Agony, Immolate, Corruption

Pet Attack => Grind => Drain Soul

If you want to cram even more functionality into that grinding button, here's the above macro, plus the feature that if you hold Alt while pressing it, it will cast Drain Soul instead.

/petattack [nomodifier]
/use [mod:alt] Drain Soul
/castsequence [nomodifier] reset=target/combat Corruption, Curse of Agony, Immolate, Shadow Bolt, Shadow Bolt, Shoot

Pet Attack => Cast DoT's in Sequence => Hold Alt to nuke

Sends your pet to attack, and casts immolate. Press again for Curse of Agony, and again for Corruption. Then hold alt, and nuke away. If you're not grouped, and have a voidwalker out, you will alternate between Shadow Bolt and Searing Pain when holding alt. I suggest you keep Immolate first as it gives you time to cast without interrupts, and lets your demon cast or attack in time to build up aggro.

/petattack
/castsequence [modifier:alt,nogroup,pet:Voidwalker/pet:Felhunter] Searing Pain, Shadow Bolt, Shadow Bolt
/cast [modifier:alt] Shadow Bolt
/castsequence reset=combat/target Immolate, Curse of Agony, Corruption

Pet Attack => Find and destroy shaman's totems

This macro sends your pet to find and destroy shaman's totems. The first totem is Fire Resistance Totem increasing the fire resistance of party members within 20 yards by XX. Where XX depend on rank of Fire Resistance Totem.) specially for firelocks for decrease fire resistances. Second totem - Windfury Totem enchants all party members main-hand weapons with wind, if they are within 20 yards. Each hit has a 20% chance of granting the attacker 1 extra attack with XXX extra attack power. Where XXX depend on rank of Windfury Totem.) - it prevent from lot of huge damages. Third totem - Earthbind Totem slowing the movement speed of enemies (it must be destroyed, specially for running locks). The fourth totem in macro - Tremor Totem blocks all fear attempts, it is very important to remove this as often as possible, this totem does not have a cooldown as such the Shaman will be able to recast as often as possible. The last totem is Grounding Totem and will block your next spell cast.

The Macro sends each command in sequence and the most recent successful command will be taken. This means that your Macro should be backwards in priority (e.g. the last totem is the most important, with the first line being the least important).

/petattack
/petattack [target=Fire Resistance Totem] 
/petattack [target=Windfury Totem]
/petattack [target=Earthbind Totem]
/petattack [target=Tremor Totem]
/petattack [target=Grounding Totem]

Voidwalker Sacrifice / Succubus Seduction / Felhunter Spell Lock & Devour Magic

This macro will do the following.

• If you have your Voidwalker summoned and are out of combat it will cast Consume Shadows, or Sacrifice if you are in combat.
• If you have your Succubus summoned it will cast Seduction on your focus or if you have no focus then it will cast Seduction on your current target.
• If you have your Felhunter summoned it will cast Spell Lock on your target with a left click and Devour Magic on you with a right click.

#showtooltip
/cast [pet:Voidwalker,combat] Sacrifice; [pet:Voidwalker] Consume Shadows; [pet:Succubus,target=focus][pet:Succubus] Seduction; [pet:Felhunter,button:2,target=player] Devour Magic; [pet:Felhunter] Spell Lock

Note If you assign the button to it will change the graphic to match whatever spell your current pet will use and will show the correct tooltip on mouseover.

All pet abilities in one button / AI

221 characters long to get the most out of all pet abilities, this macro will:
1. If you have a Succubus out, cast Seduction on your focus.
2. If you have an Imp out, cast Dark Pact.
3. if you have a Felhunter out, cast Spell Lock on your focus.
4. If in combat with a voidwalker, cast Dark Pact and then Sacrifice.
5. If out of combat with a voidwalker, cast Consume Shadows and Health Funnel.

#showtooltip
/cast [pet:Imp]Dark Pact;[pet:Succubus,target=focus]Seduction;[pet:Felhunter,target=focus]Spell Lock
/stopmacro [nopet:voidwalker]
/cast [combat]Dark Pact;Health Funnel
/cast [nocombat]Consume Shadows;Sacrifice

This is another version of the above macro which has been modified to include all of the most important pet abilities.

#showtooltip
/cast [pet:voidwalker,combat] Sacrifice
/cast [pet:Succubus,target=target] Seduction
/cast [pet:Felhunter,target=target] Spell Lock
/cast [pet:Felguard,target=target] Intercept

Imp Dark Pact / No Imp Life Tap

Dark Pact if you have an Imp out, Life Tap if you don't have an Imp out. Depending on your playstyle, this may let you get by with only 1 keybinding for both Dark Pact and Life Tap.

/cast [pet:imp] Dark Pact; Life Tap

Another variant for this macro would be to use Dark Pact if your Imp or Felhunter is out since both have a nice mana pool, otherwise use Life Tap. If you use this macro with ? as icon it will show the icon for the available spell.

#showtooltip [pet:imp/felhunter] Dark Pact; Life Tap
/cast [pet:imp/felhunter] Dark Pact; Life Tap

Devour Magic off Target else Yourself

Devour Magic on your target, Devours off of you when right clicked.

/cast [button:2,target=player] Devour Magic; Devour Magic

Fel Domination + Summon Pet

If you are demonologist and have [Fel Domination] it will cast it and summon the pet you want. Just change "pet you want to summon" with the name of your desired minion, for example /cast Summon Voidwalker (Summon).

/cast Fel Domination
/stopcasting
/cast Summon [pet you want to summon](Summon)

In addition, if you want the ability to summon more than one pet using Fel Domination with only one button, this macro works wonders. Edit for your minion preference. If Fel Domination is not up, it will summon the minion normally. NOTE: if you use the ? mark icon for the macro, you will only see the icon for Fel Domination, although the tooltip will display the correct Summon.

#showtooltip [mod:ctrl] Summon Felhunter; [mod:alt] Summon Voidwalker; [mod:shift] Summon Imp; Summon Felguard
/cast Fel Domination
/cast [mod:ctrl] Summon Felhunter; [mod:alt] Summon Voidwalker; [mod:shift] Summon Imp; Summon Felguard

4 Demons on 1 button

One button, 4 Demons. Left = Felhunter, Right = Voidwalker, Shift click = Imp, Control click = Succubus. Saves bar space.

/cast [modifier:shift]Summon Imp(Summon); [modifier:ctrl]Summon Succubus(Summon); [button:2]Summon Voidwalker(Summon); Summon Felhunter(Summon)

Focus a Target out of combat, then attack in combat

This macro will set a focus on your target outside of combat and when in combat will command your pet to either assist the focussed target if it is friendly or attack the focussed target if it is hostile. Can be modified to clear focus when used or can be made so that focus is kept so pet can be juggled between 2 targets in combat. Also, if out of combat can send your pet to attack once a focus is set. There's really a lot of ways someone can tweak with this so figure out what works for you and change to your liking.

/focus [nocombat]
/petattack [target=focus, exists,harm,combat]; [target=focustarget,exists,harm,combat]; target

Voidwalker management on one button

1. If you do not have a Voidwalker out it will summon it.
2. If you have a Voidwalker and ARE NOT in combat, will cast Consume Shadows and heal Voidwalker.
3. If you have a Voidwalker and ARE in combat, will Sacrifice Voidwalker.

/cast [nopet:Voidwalker] Summon Voidwalker
/cast [pet:Voidwalker,nocombat] Consume Shadows
/cast [pet:Voidwalker,combat] Sacrifice

A variant Voidwalker Summon/Sacrifice macro: If in combat and pet is Voidwalker, cast Sacrifice, otherwise Summon Voidwalker.

/cast [target=pet,dead] Summon Voidwalker; [combat,pet:Voidwalker] Sacrifice; Summon Voidwalker

Note: The "[target=pet,dead]" part is necessary to keep from getting a "Your pet is dead" error when resummoning shortly after casting Sacrifice.

Voidwalker Health Recovery

Often when soloing with an affliction build, a warlock ends combat with near full health and mana. This quickly gets your voidwalker back up to fighting condition in a single click. If you aren't using your voidwalker or are in combat it acts just like the normal health funnel button.

#showtooltip
/cast Health Funnel
/cast [nocombat, pet:Voidwalker] Consume Shadows

Two-button Total Pet Control

With two buttons (macros) you can have total pet control if you make them context sensitive. The point of this is that a keyboard can become utterly cluttered, and requiring more than 2 buttons for 5-6 functions on your pets results in more buttons than preferred being in an unreachable place. Before the macro I'd bind pet function 1 (attack) and 5 to two buttons, but occasionally the situation comes up where the pet needs to be recalled, or needs to be told to stay in a position in sentry mode. Using the mouse + pet bar for these more advanced techniques wastes valuable time, multiple buttons waste valuable pet space. I therefore wrote a macro to bring it all down to two buttons, based on having a target selected or not.

Macro 1:

/petfollow
/petpassive
/petattack [harm]

Macro 2:

/petfollow [pet:succubus]
/cast [harm] Spell Lock
/cast [help] Devour Magic
/cast Seduction
/cast Sacrifice
/cast Intercept
/petstay [noexists]
/petdefensive [noexists]

This allows you to do the following things:

• Send your pet to attack pressing button 1 while targeting an enemy
• Get your pet to return to you immediately by deselecting any targets and pressing the same button again
• Have your pet use its special attack (Seduce, Sacrifice, Intercept, Spell Lock) when you target an enemy with the second button
• Have your pet (other than the Voidwalker) stay in one place and become aggressive when pressing the second button and no target is selected
• Have them return again to you and become passive again pressing the first button again
• You can now re-seduce without the succubus being blocked by an ongoing seduce
• The Felhunter will attempt to devour Magic on targeted friendlies, and spell lock targeted enemies.

Basically everything you ever need to do with your pet in 2 buttons.

Another 2 button AI system

Button 1:

#showtooltip
/cast [help,pet:felhunter] Devour Magic; [pet:felhunter,target=player] Devour Magic; 
[pet:voidwalker,combat] Suffering; [pet:voidwalker,nocombat] Consume Shadows; 
[pet:succubus] Soothing Kiss

Button 2:

#showtooltip
/cast [pet:felhunter,target=target] Spell Lock;
[pet:succubus,target=target] Seduction;
[pet:voidwalker,combat] Sacrifice; [pet:voidwalker,nocombat] Consume Shadows;

When Button 1 is pressed, if you have a felhunter up and are targeting a friendly player, he will Devour Magic that player, otherwise he will devour magic on you. If you have a voidwalker up and in combat he will cast Suffering (taunt), otherwise he will cast Consume Shadows (heal). If you have a succubus up, she will cast Soothing Kiss.

When Button 2 is pressed, if you have a felhunter up he will cast Spell Lock on your target. If you have a succubus up, she will cast Seduce on your target, and if you have a voidwalker up, and are in combat he will cast Sacrifice (put in combat to help deture misclicks), otherwise he'll attempt to heal himself.

Note: use the ? as the macro icon and the actual icon per ability will appear.

Summon All Pets

This one is a very simple macro that allows you to summon any pet you wish to summon. Just left click to summon an Imp. Hold alt and left click to summon a Succubus. Hold ctrl and left click to summon a felhunter. Hold shift and left click to summon a Voidwalker. Right click to summon a Felguard. Hold shift and right click to summon a Felsteed. Hold alt and right click to summon a Dreadsteed. That covers every possible summon, includes the mounts. Even if you don't have some of the summons it doesn't matter because it'll just mean that you can't use that one until you get the spell. So lets say you don't have a Felhunter and you ctrl right click, nothing will happen. Yet all the other summons will work fine. So no matter what level you are it will work with whatever pets you have.

  #showtooltip 
  /cast [btn:2] Summon Felguard
  /cast [btn:2,mod:shift] Summon Felsteed 
  /cast [btn:2,mod:alt]  Eye of Kilrogg
  /cast [mod:alt] Summon Succubus
  /cast [mod:ctrl] Summon Felhunter
  /cast [mod:shift] Summon Voidwalker
  /cast Summon Imp

Same thing, more space efficient.

  #showtooltip 
  /cast [btn:2] Summon Felguard; [btn:2,mod:shift] Summon Felsteed; [btn:2,mod:alt] Eye of Kilrogg; [mod:alt] Summon Succubus; [mod:ctrl] Summon Felhunter; [mod:shift] Summon Voidwalker; Summon Imp

Or if you don't or can't use multiple mouse buttons, this will also work. Notice the lack of the Eye of Kilrogg, Felsteed/Dreadsteed, and Imp summons. Also be aware that if you use keyboard shortcuts (for example you press "3" for the third action button) you MUST remap your shift key to use this or any other macro that has a shift modifier. Shift+# keys switch your action bars by default.

#showtooltip
/cast [mod:alt] Summon Felguard; [mod:ctrl] Summon Voidwalker; [mod:shift] Summon Succubus; Summon Felhunter

Focused Seduction

• Upon use, the macro will Focus your target, and have your succubus Seduce it.
• When used for the second time, and your Focused target, i.e. the Seduction target, is alive, it will re-seduce it, regardless of what your current target is. It will not focus your current target, and seduce that; it will re-seduce it's focused target.
• If used during Seduction, it will break the seduction and re-seduce the focused target.
• If clicked while "Alt" is being pressed, it will cancel the previous focus and assign a new focus on your current target.

#show Seduction
/clearfocus [modifier:alt] 
/focus [target=focus,noexists]; [target=focus,dead] 
/clearfocus [target=focus,help] 
/petstay 
/petfollow 
/stopcasting 
/cast [pet:succubus,target=focus,exists,harm] Seduction; Seduction

Devour Magic - 3v3 Arena Style

• On use, this macro will cast Devour Magic on the target specified without breaking your current target.
• Useful for 3v3 Arenas, requires a middle mouse button.

#showtooltip
/cast [pet:Felhunter,button:1,target=party1] Devour Magic; 
/cast [pet:Felhunter,button:2,target=party2] Devour Magic;
/cast [pet:Felhunter,button:3,target=player] Devour Magic;

Again, same thing more space saving, and using modifiers rather than mouse buttons (for those keyboard enthusiasts out there). Normal click will cast it on you, alt+click (or alt+hotkey) will cast it on party member 1, ctrl+click (or hotkey) will cast it on party 2. Since only the Felhunter has Devour Magic, there's no need to ensure that the Felhunter is out. I recommend replacing your normal Devour Magic button on your pet toolbar with one of these.

#showtooltip
/cast [mod:alt,target=party1] Devour Magic; [mod:ctrl,target=party2] Devour Magic; [target=player] Devour Magic

Advanced Spell Lock with Focus

• When used, this macro will focus your current target (if you don't already have a focus) and cast Spell Lock on that target. If shift is held down while using this macro it will focus your current target and cast Spell Lock on that target (changing focus), if you don't have a target it will simply clear your focus. If ctrl is held down while using this macro it will simply Spell Lock the target your mouse is hovering (this way you won't lose your current target).

#showtooltip Spell Lock
/clearfocus [modifier:shift]
/focus [target=focus, noexists]
/cast [nomodifer, pet:Felhunter, target=focus, harm] Spell Lock; [modifier:ctrl, pet:Felhunter, target=mouseover, harm] Spell Lock

Advanced Devour Magic

• When used, this macro will cast Devour Magic on you. If shift is held down while using this macro it will cast Devour Magic on your current target.

#showtooltip Devour Magic
/cast [modifier:shift, pet:Felhunter] Devour Magic; [pet:Felhunter, target=player] Devour Magic

Pet summon

• This will consolidate your pets on to one button, I wrote it far before 70, so you will likely want to rearrange it. As-is, it summons Imp by default, Voidwalker if you hold shift, Succubus with ctrl, and Felhunter with alt. Right click would, intuitively, be dismiss, but I preferred to use it to hold my mount, though you may want to put another pet there, which would be easily done by copying from the macro. It's actually set to "not left click."

#showtooltip
/cast [nobutton:1] Summon Felsteed(Summon)
/cast [nomodifier] Summon Imp(Summon)
/cast [modifier:shift] Summon Voidwalker(Summon)
/cast [modifier:ctrl] Summon Succubus(Summon)
/cast [modifier:alt] Summon Felhunter(Summon)

Pet Assist -> Grind -> Drain Soul

• I wanted to maximize my functionality grinding especially pulling multiple mobs but I also wanted to get most of my mana back as well by clicking on my pet's target (which was generally lower hp than the rest). So I made this macro that if the pet is attacking it will cast drain soul, and if even if the pet is not attacking it will still cast drain soul

#Showtooltip
/cast [exists,target=pettarget] Drain Soul
/cast [exists,nodead] Drain Soul

Stone Management

Create and use Firestone or Spellstone

With 3.0, firestones and spellstones were changed to work like weapon oils. No longer equipped in the relic slot, instead they each have 5 charges and are cast upon your weapon with a one hour duration. This macro will attempt to make a new firestone or spellstone (with alt) and it will also attempt to put the specified stone on your weapon if you already have one. It also closes the annoying "do you want to replace" popup message if you already have an oil or stone on your weapon and disables sound effects so you don't have to hear the click. Change "Master" to "Grand" at level 80.

/console Sound_EnableSFX 0
/cast [mod:alt] Create Spellstone; Create Firestone
/use [mod:alt] Master Spellstone; Master Firestone
/use 16
/click StaticPopup1Button1
/console Sound_EnableSFX 1

Soulstone Macro

This macro will on right click make a soulstone (change for appropriate level), left click, use it and on alt left click cast it on yourself.

#showtooltip Minor Soulstone
/cast [modifier:alt,target=player] Minor Soulstone; [button:1] Minor Soulstone;  [button:2] Create Soulstone

Healthstone and Healing Potion

Note: It is currently impossible to write a macro that will have you use a healthstone if you have one and a potion if you do not.

• Left-click uses a Healthstone; right-click a potion named in the macro
• If you choose an icon for the macro rather than allowing the program to choose one for you, the macro button in your action bar will be grayed if you do not have a healthstone.
• In all cases, only the cooldown for your healthstone will be shown.

#showtooltip
/use [button:1] Healthstone; [button:2] Superior Healing Potion

This macro summons a Healthstone if you are not in combat, uses a Healthstone AND potion if you are. Note, depending on whether you have a Healthstone and/or potion in inventory at the time (and applicable cooldowns), you may see error messages. The macro also cannot tell whether you have a Healthstone in inventory or not. These are unavoidable - the macro will still do the best it can. NB: You must edit this to indicate the correct Healthstone and healing potion names.

/cast [nocombat]Create Lesser Healthstone	 
/use [combat]Lesser Healthstone	 
/use [combat]Lesser Healing Potion

Healthstone use/summon, Ritual of Souls in group

This will allow to use a healthstone with one click, summon with another, however in groups you will cast Ritual of Souls rather than a single summon.

#showTooltip Master Healthstone
/cast [group, button:2] Ritual of souls
/cast [button:2] Create Healthstone
/use [button:1] Master Healthstone

When you first log in it'll show you a red question mark icon until you make your first stone. You can change the first line to "#showTooltip Create Master Healthstone" to fix this, however it will display the number of soulshards remaining instead of healthstone.

Healthstone use/summon, Soulstone use/summon and Ritual of Souls on one button

Your two favorites stones fast and easy to use. To optimize it, select the question mark icon.

#showtooltip
/use [nomodifier, button:1] Fel Healthstone
/cast [nomodifier, button:2] Create Healthstone
/use [mod:shift, button:1] Demonic Soulstone
/cast [mod:shift, button:2] Create Soulstone
/cast [mod:alt, button:1] Ritual of Souls

Now, left click will use your Healthstone (here, the Fel Healthstone from level 80), and right click will summon it. If you hold shift, left click will use your Soulstone (here it is a Demonic Soulstone, again level 80 version), and right click summon the stone. At last, holding alt will let you begin your Ritual of Souls.

When using first, you'll have just the question mark. Summon a healthstone to get the tooltip upgraded (it won't work for the summoning spells though).

Soul Shard management

These macros are for those who do not want to worry about an addon like Necrosis or eeShard to manage shards and inventory room.

Destroy a single shard

When your bags are full and a world drop happens, you don't want to have to open your bags to find and destroy a soul shard. Use this macro to destroy exactly one. Good for those who do not use a shard bag and don't necessarily want a static cap on the number of shards to carry. Also, this destroys the shard furthest to the "right" in your bags, i.e., if you have a soul bag in the left slot, it will destroy those shards in another bag first.

/run i="Soul Shard"d=1 for x=0,4 do for y=1,GetContainerNumSlots(x) do  if (d>0) then l=GetContainerItemLink(x,y)  if l and GetItemInfo(l)==i then PickupContainerItem(x,y) DeleteCursorItem() d=d-1 end end end end

Destroy all but a specified number of shards

This will destroy any shards in excess of a designated number. As written, the number is twenty. Change the "20" in "d=GetItemCount(i)-20" to set the number of shards you want to carry. Like the macro above, this will destroy the shards furthest to the "right" in your inventory.

/run i="Soul Shard"d=GetItemCount(i)-20 for x=0,4 do for y=1,GetContainerNumSlots(x) do  if (d>0) then l=GetContainerItemLink(x,y) if l and GetItemInfo(l)==i then PickupContainerItem(x,y) DeleteCursorItem() d=d-1 end end end end